Porting my CPAN distribution LCS::BV is a nice task. It's short code, has full test coverage and allows benchmarks. Also it could be expected that LCS::BV (a bit-vector implementation of the Longest Common Subsequence algorithm) will be faster than the Perl6 port of Algorithm::Diff and the Perl6 module Algorithm::LCS. LCS::BV is as fast as the XS version of A::D, see my blogpost Tuning Algorithm::Diff.
Test dependencies
LCS algorithms are complex beasts. It's nearly impossible to implement them without good test cases. One problem is, that these algorithms find a sequence of maximum length, but only one of maybe more possible solutions. All possible solutions are provided by the slow CPAN distribution LCS and the method allLCS() as explained in a another blog post. So I need to port this to Perl 6 first.
To compare the results during tests Test::Deep is needed. Should be no problem, sure somebody already ported it. Or not? No, there is no Test::Deep on modules.perl6.org. So I need to port this too, or the part needed. Or not?
This is the relevant part of the tests in Perl 5:
use Test::More;
use Test::Deep;
use LCS;
use LCS::BV;
cmp_deeply(
LCS::BV->LCS(\@a,\@b),
any(@{LCS->allLCS(\@a,\@b)} ),
"$a, $b"
);
done_testing;
# say so $[[2,3],[2,4],] eqv $[[[0,1],[2,3],],[[0,1],[2,4],]].any;
my sub any_of ($result, $expected) {
return so $result eqv $expected.any;
}
ok(
any_of(
LCS::BV::LCS($A, $B),
LCS::All::allLCS($A, $B),
),
"'$a', '$b'",
);
That's an example how many features of Perl 6 are worth the half of CPAN.
Length of an integer
In Perl 5 bit operations are limited to length of an integer. In most implementations this is 64 bits, but can be 32 bits. If an array is mapped to bits it needs ceil(array_length/integer_width) integers.
This needs the following code in Perl 5:
our $width = int 0.999+log(~0)/log(2);
use integer;
no warnings 'portable'; # for 0xffffffffffffffff
my $positions;
# $a ... array of elements, e.g. ['f','o','o']
$positions->{$a->[$_]}->[$_ / $width] |= 1 << ($_ % $width)
for $amin..$amax;
# gives {'f' => [ 0b001 ], 'o' => [ 0b110 ], }Doing this the first time in Perl 6, I wondered how long integers are and how to find out. Took me very long with the result: infinite. That's awesome.
This part ported to Perl 6:
my $positions;
$positions{$a[$_]} +|= 1 +< $_ for $amin..$amax;
This is approximately half the code. You can imagine that the rest of the code also gets simpler. It also is the half.
Just 30 lines
For rosettacode.org I adapted the code for strings and removed the usual prefix and suffix optimization, see Bit Vector:
sub lcs(Str $xstr, Str $ystr) {
my ($a,$b) = ([$xstr.comb],[$ystr.comb]);
my $positions;
for $a.kv -> $i,$x { $positions{$x} +|= 1 +< $i };
my $S = +^0;
my $Vs = [];
my ($y,$u);
for (0..+$b-1) -> $j {
$y = $positions{$b[$j]} // 0;
$u = $S +& $y;
$S = ($S + $u) +| ($S - $u);
$Vs[$j] = $S;
}
my ($i,$j) = (+$a-1, +$b-1);
my $result = "";
while ($i >= 0 && $j >= 0) {
if ($Vs[$j] +& (1 +< $i)) { $i-- }
else {
unless ($j && +^$Vs[$j-1] +& (1 +< $i)) {
$result = $a[$i] ~ $result;
$i--;
}
$j--;
}
}
return $result;
}
You can install LCS::BV and LCS::All via Panda or clone them from github.
Summary
Perl 6 has a lot of convenience, allows short and clear code. It's huge. But learning all the nice features is easier than I thought. Understanding e.g. any() and trying it out in the REPL is a magnitude faster, than searching in CPAN, reading docs and trying out some distributions.
